display admins in message

[Ni3ls]

Hi all,

I made a !comment that will show the admins who are on the server

		case "admins":
		if(!isdefined(self.pers["admin"]) || self.pers["admin"] <1)
		{
			//self iprintlnbold("RANK: "+self.rank);
			self iprintlnbold("No Admin");
			return;
		}
          		players_to_admins = []; // changed
            	players = getentarray("player", "classname");
            		for (i = 0; i < players.size; i++)
					{
                		if (players[i].pers["admin"] == 1)
                    			players_to_admins[players_to_admins.size] = players[i]; // changed

            }
            
            if (players_to_admins.size == 1) 
			{
				mp = "Admins online: ";	
				mp += players_to_admins[0].name + "^1(^7"+players_to_admins[0].loginname + "^1)" + " ";
            } 
			else if (players_to_admins.size >= 2)
			{
                			mp = "Admins online: ";
                			for (i = 0; i < players_to_admins.size; i++)
								mp += players_to_admins[i].name + "^1(^7"+players_to_admins[i].loginname + "^1)" + " ";
            } 
			else 
			{
                			mp = "No Admins online";
            }

 	 		self thread tellMessage(mp);
			return;

For 1 player and 0 admins it works. However, when there are more than 1 admins, the message isnt shown.

Param 0 needs to be an int, >make function for this<=0 given! NumParams=2
Param 1 needs to be a string, >make function for this<=0 given! NumParams=2

1 of those is the error :P

[maxdamage99]

Maybe show

tellmessage(mp)

??

[Ni3ls]

tellMessage(message)
{
		sendgameservercommand(self getentitynumber(), "h \"console: " + message + "\"");
		//sendgameservercommand(-1, "h \"" + self.name + "^7: " + command + "\"");  
}

[kung foo man]

Using http://jsbeautifier.org/:

		        case "admins":
            if (!isdefined(self.pers["admin"]) || self.pers["admin"] < 1) {
                //self iprintlnbold("RANK: "+self.rank);
                self iprintlnbold("No Admin");
                return;
            }
            players_to_admins = []; // changed
            players = getentarray("player", "classname");
            for (i = 0; i < players.size; i++) {
                if (players[i].pers["admin"] == 1)
                    players_to_admins[players_to_admins.size] = players[i]; // changed

            }

            if (players_to_admins.size == 1) {
                mp = "Admins online: ";
                mp += players_to_admins[0].name + "^1(^7" + players_to_admins[0].loginname + "^1)" + " ";
            } else if (players_to_admins.size >= 2) {
                mp = "Admins online: ";
                for (i = 0; i < players_to_admins.size; i++)
                    mp += players_to_admins[i].name + "^1(^7" + players_to_admins[i].loginname + "^1)" + " ";
            } else {
                mp = "No Admins online";
            }

            self thread tellMessage(mp);
            return; 
	

The variable "mp" is local INSIDE the if, outside it will be undefined. Just declare it beforehand:

		            mp = ""; // FIX
            if (players_to_admins.size == 1) {
                mp = "Admins online: ";
                mp += players_to_admins[0].name + "^1(^7" + players_to_admins[0].loginname + "^1)" + " ";
            } else if (players_to_admins.size >= 2) {
                mp = "Admins online: ";
                for (i = 0; i < players_to_admins.size; i++)
                    mp += players_to_admins[i].name + "^1(^7" + players_to_admins[i].loginname + "^1)" + " ";
            } else {
                mp = "No Admins online";
            } 
	

[Ni3ls]

Now there isnt any message shown at all

Param 1 needs to be a string, >make function for this<=0 given! NumParams=2

[kung foo man]

There is no libcod function called whose first argument is a string, so you either changed sendgameservercommand() to something else or the error is now somewhere else. Just add a bunch of "printf(a, b, c)", it will automatically iterate over the arguments and stringify them if possible.

[IzNoGoD]

Mostly that error happens when you send an undefined var to a function expecting a non-undefined var.

did you try with developer 1 yet

[maxdamage99]

		showadmins()
{
admins="";
players = getentarray("player", "classname");
for(i = 0; i < players.size; i++)
{
if(players[i].permissions["admin"])
{
if(admins=="")
{
admins+=monotone(players[i].name);
}
else if(admins!="") 
{ 
admins+="^7, "+monotone(players[i].name);
}
}
else if(admins=="" && i==players.size) 
{
sendGameServerCommand(self getEntityNumber(), "h \""+level.consolename+"^3Admins ^7are not present on the server \"");
}
}
if(admins!="")
sendGameServerCommand(self getEntityNumber(), "h \""+level.consolename+"^3Admins^7: "+admins+" \"");
} 
	

Show message:
myserver: Admins: Admin name1, Admin name2, Admin name3
or
myserver: Admins are not present on the server

[filthy_freak_]

		showadmins()
{
    admins="";
    players = getentarray("player", "classname");
    for(i = 0; i < players.size; i++)
    {
        if(players[i].permissions["admin"])
        {
            if(admins.size)
                admins += "^7, " + monotone(players[i].name);
            else
                admins += monotone(players[i].name);
        }
    }
    if(admins.size)
        sendGameServerCommand(self getEntityNumber(), "h \"" + level.consolename + "^3Admins^7: " + admins + " \"");
    else
        sendGameServerCommand(self getEntityNumber(), "h \"" + level.consolename + "^3Admins ^7are not present on the server \"");
} 
	

Same code as above but easier to read.

[maxdamage99]

Ty : )