PDA

View Full Version : Disappearing text?



EvoloZz
20th December 2012, 12:36
Hey again, and sorry if I am asking too much, I don't know any better way to learn.
But I created 2 huds with some text, so I want the first hud disappear slowly after 20 sec (for example like "Visit killtube.org" on K~ servers) , then it shows the second hud and it disappears after 20 sec also, so it would just loop between two huds. :P
My setup:

ShowText2()
{

if(!isDefined(self.text_left))
{
self.text_left = newClientHudElem(self);
self.text_left.x = 259;
self.text_left.y = 35;
self.text_left.alignX = "left";
self.text_left.alignY = "middle";
self.text_left.sort = 1;
self.text_left.alpha = 1;
self.text_left.fontScale = 1.7;
self.text_left.archived = true;
self.text_left setText(game["hud_text2"]);
}
}

I will create second HUD later :P

Thanks!

~EvoloZz

IzNoGoD
20th December 2012, 12:55
function()
{
self endon("disconnect");

hud = newclienthudelem(self);

hud.x = something;
hud.y = alsosomething;
hud.otherstuff = set_everything_here_except_text;

hud.alpha = 0;

while(true)
{
hud settext(&"first_precached_text");

hud fadeovertime(20);
hud.alpha = 1;
wait 20;

hud fadeovertime(20);
hud.alpha = 0;
wait 20;

hud settext(&"new_precached_text_here");

hud fadeovertime(20);
hud.alpha = 1;
wait 20;

hud fadeovertime(20);
hud.alpha = 0;
wait 20;
}
}

kung foo man
20th December 2012, 14:10
This is the code used in Killtube servers:



addAd(ad, scale, color)
{
if ( ! isDefined(level.ad))
level.ad = [];
i = level.ad.size;
level.ad[i] = spawnstruct();
level.ad[i].ad = ad;
level.ad[i].scale = scale;
level.ad[i].color = color;
}

precache()
{
for (i=0; i<level.ad.size; i++)
precacheString(level.ad[i].ad);
}

ad()
{
level.hud_ad = newHudElem();
level.hud_ad.horzAlign = "fullscreen";
level.hud_ad.vertAlign = "fullscreen";
level.hud_ad.alignX = "center";
level.hud_ad.alignY = "top";
level.hud_ad.x = 320;
level.hud_ad.y = 380;
level.hud_ad.alpha = 0;

wait 10;

while (1)
{
for (i=0; i<level.ad.size; i++)
{
level.hud_ad.fontscale = level.ad[i].scale;
level.hud_ad.color = level.ad[i].color;
level.hud_ad fadeOverTime(1);
level.hud_ad.alpha = 1;
level.hud_ad.label = level.ad[i].ad;
wait 10;
level.hud_ad fadeOverTime(1);
level.hud_ad.alpha = 0;
wait 20;
}
}
}



Call it like this in startgametype():



std\ad::addAd(&"Visit killtube.org! first message...", 2, (1,0,0));
std\ad::addAd(&"Visit killtube.org! second message...", 2, (1,0,0));
std\ad::addAd(&"Visit killtube.org! third message...", 2, (1,0,0));
std\ad::precache();